aboutsummaryrefslogtreecommitdiffstats
path: root/mode-button
blob: 217c0cc84138143264f337d66eb5f7dab05742f7 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
#!rsc by RouterOS
# RouterOS script: mode-button
# Copyright (c) 2018-2020 Christian Hesse <mail@eworm.de>
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
#
# act on multiple mode and reset button presses
# https://git.eworm.de/cgit/routeros-scripts/about/doc/mode-button.md

:global ModeButton;

:global LogPrintExit;

:set ($ModeButton->"count") ($ModeButton->"count" + 1);

:local Scheduler [ / system scheduler find where name="ModeButtonScheduler" ];

:if ([ :len $Scheduler ] = 0) do={
  $LogPrintExit info ("Creating scheduler ModeButtonScheduler, counting presses...") false;
  :global ModeButtonScheduler do={
    :global ModeButton;

    :global LogPrintExit;
    :global ModeButtonScheduler;

    :local LEDInvert do={
      :global ModeButtonLED;

      :global IfThenElse;

      :local LED [ / system leds find where leds=$ModeButtonLED type~"^(on|off)\$" interface=[] ];
      :if ([ :len $LED ] = 0) do={
        :return false;
      }
      / system leds set type=[ $IfThenElse ([ get $LED type ] = "on") "off" "on" ] $LED;
    }

    :local Count ($ModeButton->"count");
    :local Code ($ModeButton->[ :tostr $Count ]);

    :set ($ModeButton->"count") 0;
    :set ModeButtonScheduler;
    / system scheduler remove ModeButtonScheduler;

    :if ([ :len $Code ] > 0) do={
      $LogPrintExit info ("Acting on " . $Count . " mode-button presses: " . $Code) false;

      :for I from=1 to=$Count do={
        $LEDInvert;
        :if ([ / system routerboard settings get silent-boot ] = false) do={
          :beep length=200ms;
        }
        :delay 200ms;
        $LEDInvert;
        :delay 200ms;
      }

      [ :parse $Code ];
    } else={
      $LogPrintExit info ("No action defined for " . $Count . " mode-button presses.") false;
    }
  }
  / system scheduler add name="ModeButtonScheduler" \
      on-event=":global ModeButtonScheduler; \$ModeButtonScheduler;" interval=3s;
} else={
  $LogPrintExit debug ("Updating scheduler ModeButtonScheduler...") false;
  / system scheduler set $Scheduler start-time=[ /system clock get time ];
}