daily-psk: add support for wifiwave2

3 files changed, 116 insertions, 8 deletions

diff --git a/daily-psk.template.rsc b/daily-psk.template.rsc
index ea0fb46..125e6c5 100644
--- a/daily-psk.template.rsc
+++ b/daily-psk.template.rsc
@@ -56,12 +56,17 @@ $WaitFullyConnected;
 :local NewPsk [ $GeneratePSK $Date ];
 
 :foreach AccList in=[ /caps-man/access-list/find where comment~$DailyPskMatchComment ] do={
+:foreach AccList in=[ /interface/wifiwave2/access-list/find where comment~$DailyPskMatchComment ] do={
 :foreach AccList in=[ /interface/wireless/access-list/find where comment~$DailyPskMatchComment ] do={
   :local SsidRegExp [ /caps-man/access-list/get $AccList ssid-regexp ];
+  :local SsidRegExp [ /interface/wifiwave2/access-list/get $AccList ssid-regexp ];
   :local Configuration ([ /caps-man/configuration/find where ssid~$SsidRegExp ]->0);
+  :local Configuration ([ /interface/wifiwave2/configuration/find where ssid~$SsidRegExp ]->0);
   :local Ssid [ /caps-man/configuration/get $Configuration ssid ];
+  :local Ssid [ /interface/wifiwave2/configuration/get $Configuration ssid ];
   :local OldPsk [ /caps-man/access-list/get $AccList private-passphrase ];
-  # /caps-man above - /interface/wireless below
+  :local OldPsk [ /interface/wifiwave2/access-list/get $AccList passphrase ];
+  # /caps-man /interface/wifiwave2 above - /interface/wireless below
   :local IntName [ /interface/wireless/access-list/get $AccList interface ];
   :local Ssid [ /interface/wireless/get $IntName ssid ];
   :local OldPsk [ /interface/wireless/access-list/get $AccList private-pre-shared-key ];
@@ -70,9 +75,11 @@ $WaitFullyConnected;
   :if ($NewPsk != $OldPsk) do={
     $LogPrintExit2 info $0 ("Updating daily PSK for " . $Ssid . " to " . $NewPsk . " (was " . $OldPsk . ")") false;
     /caps-man/access-list/set $AccList private-passphrase=$NewPsk;
+    /interface/wifiwave2/access-list/set $AccList passphrase=$NewPsk;
     /interface/wireless/access-list/set $AccList private-pre-shared-key=$NewPsk;
 
     :if ([ :len [ /caps-man/actual-interface-configuration/find where configuration.ssid=$Ssid !disabled ] ] > 0) do={
+    :if ([ :len [ /interface/wifiwave2/actual-configuration/find where configuration.ssid=$Ssid ] ] > 0) do={
     :if ([ :len [ /interface/wireless/find where name=$IntName !disabled ] ] = 1) do={
       :foreach SeenSsid in=$Seen do={
         :if ($SeenSsid = $Ssid) do={
diff --git a/daily-psk.wifiwave2.rsc b/daily-psk.wifiwave2.rsc
new file mode 100644
index 0000000..40c79cd
--- /dev/null
+++ b/daily-psk.wifiwave2.rsc
@@ -0,0 +1,90 @@
+#!rsc by RouterOS
+# RouterOS script: daily-psk.wifiwave2
+# Copyright (c) 2013-2023 Christian Hesse <mail@eworm.de>
+#                         Michael Gisbers <michael@gisbers.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+#
+# update daily PSK (pre shared key)
+# https://git.eworm.de/cgit/routeros-scripts/about/doc/daily-psk.md
+#
+# !! Do not edit this file, it is generated from template!
+
+:local 0 "daily-psk.wifiwave2";
+:global GlobalFunctionsReady;
+:while ($GlobalFunctionsReady != true) do={ :delay 500ms; }
+
+:global DailyPskMatchComment;
+:global DailyPskQrCodeUrl;
+:global Identity;
+
+:global FormatLine;
+:global LogPrintExit2;
+:global ScriptLock;
+:global SendNotification2;
+:global SymbolForNotification;
+:global UrlEncode;
+:global WaitForFile;
+:global WaitFullyConnected;
+
+$ScriptLock $0;
+$WaitFullyConnected;
+
+# return pseudo-random string for PSK
+:local GeneratePSK do={
+  :local Date [ :tostr $1 ];
+
+  :global DailyPskSecrets;
+
+  :global ParseDate;
+
+  :set Date [ $ParseDate $Date ];
+
+  :local A ((14 - ($Date->"month")) / 12);
+  :local B (($Date->"year") - $A);
+  :local C (($Date->"month") + 12 * $A - 2);
+  :local WeekDay (7000 + ($Date->"day") + $B + ($B / 4) - ($B / 100) + ($B / 400) + ((31 * $C) / 12));
+  :set WeekDay ($WeekDay - (($WeekDay / 7) * 7));
+
+  :return (($DailyPskSecrets->0->(($Date->"day") - 1)) . \
+    ($DailyPskSecrets->1->(($Date->"month") - 1)) . \
+    ($DailyPskSecrets->2->$WeekDay));
+}
+
+:local Seen ({});
+:local Date [ /system/clock/get date ];
+:local NewPsk [ $GeneratePSK $Date ];
+
+:foreach AccList in=[ /interface/wifiwave2/access-list/find where comment~$DailyPskMatchComment ] do={
+  :local SsidRegExp [ /interface/wifiwave2/access-list/get $AccList ssid-regexp ];
+  :local Configuration ([ /interface/wifiwave2/configuration/find where ssid~$SsidRegExp ]->0);
+  :local Ssid [ /interface/wifiwave2/configuration/get $Configuration ssid ];
+  :local OldPsk [ /interface/wifiwave2/access-list/get $AccList passphrase ];
+  :local Skip 0;
+
+  :if ($NewPsk != $OldPsk) do={
+    $LogPrintExit2 info $0 ("Updating daily PSK for " . $Ssid . " to " . $NewPsk . " (was " . $OldPsk . ")") false;
+    /interface/wifiwave2/access-list/set $AccList passphrase=$NewPsk;
+
+    :if ([ :len [ /interface/wifiwave2/actual-configuration/find where configuration.ssid=$Ssid ] ] > 0) do={
+      :foreach SeenSsid in=$Seen do={
+        :if ($SeenSsid = $Ssid) do={
+          $LogPrintExit2 debug $0 ("Already sent a mail for SSID " . $Ssid . ", skipping.") false;
+          :set Skip 1;
+        }
+      }
+
+      :if ($Skip = 0) do={
+        :set Seen ($Seen, $Ssid);
+        :local Link ($DailyPskQrCodeUrl . \
+            "?scale=8&level=1&ssid=" . [ $UrlEncode $Ssid ] . "&pass=" . [ $UrlEncode $NewPsk ]);
+        $SendNotification2 ({ origin=$0; \
+          subject=([ $SymbolForNotification "calendar" ] . "daily PSK " . $Ssid); \
+          message=("This is the daily PSK on " . $Identity . ":\n\n" . \
+            [ $FormatLine "SSID" $Ssid ] . "\n" . \
+            [ $FormatLine "PSK" $NewPsk ] . "\n" . \
+            [ $FormatLine "Date" $Date ] . "\n\n" . \
+            "A client device specific rule must not exist!"); link=$Link });
+      }
+    }
+  }
+}
diff --git a/doc/daily-psk.md b/doc/daily-psk.md
index 9a5e558..60a645f 100644
--- a/doc/daily-psk.md
+++ b/doc/daily-psk.md
@@ -21,17 +21,24 @@ Requirements and installation
 
 Just install this script.
 
-Depending on whether you use CAPsMAN (`/caps-man`) or local wireless
-interface (`/interface/wireless`) you need to install a different script
-and add schedulers to run the script:
+Depending on whether you use `wifiwave2` package (`/interface/wifiwave2`)
+or legacy wifi with CAPsMAN (`/caps-man`) or local wireless interface
+(`/interface/wireless`) you need to install a different script and add
+schedulers to run the script:
 
-For CAPsMAN:
+For `wifiwave2`:
+
+    $ScriptInstallUpdate daily-psk.wifiwave2;
+    /system/scheduler/add interval=1d name=daily-psk on-event="/system/script/run daily-psk.wifiwave2;" start-time=03:00:00;
+    /system/scheduler/add name=daily-psk@startup on-event="/system/script/run daily-psk.wifiwave2;" start-time=startup;
+
+For legacy CAPsMAN:
 
     $ScriptInstallUpdate daily-psk.capsman;
     /system/scheduler/add interval=1d name=daily-psk on-event="/system/script/run daily-psk.capsman;" start-time=03:00:00;
     /system/scheduler/add name=daily-psk@startup on-event="/system/script/run daily-psk.capsman;" start-time=startup;
 
-For local interface:
+For legacy local interface:
 
     $ScriptInstallUpdate daily-psk.local;
     /system/scheduler/add interval=1d name=daily-psk on-event="/system/script/run daily-psk.local;" start-time=03:00:00;
@@ -51,11 +58,15 @@ The configuration goes to `global-config-overlay`, these are the parameters:
 > [`global-config`](../global-config.rsc) (the one without `-overlay`) to
 > your local `global-config-overlay` and modify it to your specific needs.
 
-Then add an access list entry. For CAPsMAN:
+Then add an access list entry. For `wifiwave2`:
+
+    /interface/wifiwave2/access-list/add comment="Daily PSK" ssid-regexp="-guest\$" passphrase="ToBeChangedDaily";
+
+For legacy CAPsMAN:
 
     /caps-man/access-list/add comment="Daily PSK" ssid-regexp="-guest\$" private-passphrase="ToBeChangedDaily";
 
-For local interface:
+For legacy local interface:
 
     /interface/wireless/access-list/add comment="Daily PSK" interface=wl-daily private-pre-shared-key="ToBeChangedDaily";