update-gre-address


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24

#!rsc
# RouterOS script: update-gre-address
# Copyright (c) 2013-2018 Christian Hesse <mail@eworm.de>
#
# update gre interface remote address with dynamic address from
# ipsec remote peer

/ interface gre set remote-address=0.0.0.0 disabled=yes [ find where !running !disabled ];

:foreach peer in=[ / ip ipsec remote-peers find ] do={
  :local id [ / ip ipsec remote-peers get $peer id ];
  :local greint [ / interface gre find where comment=$id ];
  :if ([ :len $greint ] > 0) do={
    :local grename [ / interface gre get $greint name ];
    :local addrold [ / interface gre get $greint remote-address ];
    :local disabled [ / interface gre get $greint disabled ];
    :local addrnew [ / ip ipsec remote-peers get $peer dynamic-address ];
    :if ($addrnew != $addrold || $disabled = true) do={
      :log info ("Update remote address for interface " . $grename . " to " . $addrnew);
      / interface gre set remote-address=0.0.0.0 disabled=yes [ find where remote-address=$addrnew name!=$grename ];
      / interface gre set $greint remote-address=$addrnew disabled=no;
    }
  }
}