aboutsummaryrefslogtreecommitdiffstats
path: root/ipv6-update
blob: b81a0eceb7088ee65ed19d895cf60538861a9f99 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
#!rsc by RouterOS
# RouterOS script: ipv6-update
# Copyright (c) 2013-2022 Christian Hesse <mail@eworm.de>
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
#
# update firewall and dns settings on IPv6 prefix change
# https://git.eworm.de/cgit/routeros-scripts/about/doc/ipv6-update.md

:local 0 "ipv6-update";
:global GlobalFunctionsReady;
:while ($GlobalFunctionsReady != true) do={ :delay 500ms; }

:local PdPrefix $"pd-prefix";

:global LogPrintExit2;
:global ParseKeyValueStore;

:if ([ :typeof $PdPrefix ] = "nothing") do={
  $LogPrintExit2 error $0 ("This script is supposed to run from ipv6 dhcp-client.") true;
}

:local Pool [ /ipv6/pool/get [ find where prefix=$PdPrefix ] name ];
:if ([ :len [ /ipv6/firewall/address-list/find where comment=("ipv6-pool-" . $Pool) ] ] = 0) do={
  /ipv6/firewall/address-list/add list=("ipv6-pool-" . $Pool) address=:: comment=("ipv6-pool-" . $Pool);
  $LogPrintExit2 warning $0 ("Added ipv6 address list entry for ipv6-pool-" . $Pool) false;
}
:local AddrList [ /ipv6/firewall/address-list/find where comment=("ipv6-pool-" . $Pool) ];
:local OldPrefix [ /ipv6/firewall/address-list/get ($AddrList->0) address ];

:if ($OldPrefix != $PdPrefix) do={
  $LogPrintExit2 info $0 ("Updating IPv6 address list with new IPv6 prefix " . $PdPrefix) false;
  /ipv6/firewall/address-list/set address=$PdPrefix $AddrList;

  # give the interfaces a moment to receive their addresses
  :delay 2s;

  :foreach ListEntry in=[ /ipv6/firewall/address-list/find where comment~("^ipv6-pool-" . $Pool . ",") ] do={
    :local ListEntryVal [ /ipv6/firewall/address-list/get $ListEntry ];
    :local Comment [ $ParseKeyValueStore ($ListEntryVal->"comment") ];

    :local Address [ /ipv6/address/find where from-pool=$Pool interface=($Comment->"interface") ];
    :if ([ :len $Address ] = 1) do={
      :set Address [ /ipv6/address/get $Address address ];
      $LogPrintExit2 info $0 ("Updating IPv6 address list with new IPv6 prefix " . $Address . \
        " from interface " . ($Comment->"interface")) false;
      /ipv6/firewall/address-list/set address=$Address $ListEntry;
    }
  }

  :foreach Record in=[ /ip/dns/static/find where comment~("^ipv6-pool-" . $Pool . ",") ] do={
    :local RecordVal [ /ip/dns/static/get $Record ];
    :local Comment [ $ParseKeyValueStore ($RecordVal->"comment") ];

    :local Prefix [ /ipv6/address/get [ find where interface=($Comment->"interface") from-pool=$Pool global ] address ];
    :set Prefix ([ :toip6 [ :pick $Prefix 0 [ :find $Prefix "/64" ] ] ] & ffff:ffff:ffff:ffff::);
    :local Address ($Prefix | ([ :toip6 ($RecordVal->"address") ] & ::ffff:ffff:ffff:ffff));

    $LogPrintExit2 info $0 ("Updating DNS record for " . ($RecordVal->"name") . \
      ($RecordVal->"regexp") . " to " . $Address) false;
    /ip/dns/static/set address=$Address $Record;
  }
}