aboutsummaryrefslogtreecommitdiffstats
path: root/firmware-upgrade-reboot
blob: 27bbe41746df0330e63011d083e64300379560c8 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
#!rsc by RouterOS
# RouterOS script: firmware-upgrade-reboot
# Copyright (c) 2022 Christian Hesse <mail@eworm.de>
# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
#
# install firmware upgrade, and reboot
# https://git.eworm.de/cgit/routeros-scripts/about/doc/firmware-upgrade-reboot.md

:local 0 "firmware-upgrade-reboot";
:global GlobalFunctionsReady;
:while ($GlobalFunctionsReady != true) do={ :delay 500ms; }

:global LogPrintExit2;
:global VersionToNum;

:local RouterBoard [ /system/routerboard/get ];
:if ($RouterBoard->"current-firmware" = $RouterBoard->"upgrade-firmware") do={
  $LogPrintExit2 info $0 ("Firmware is already up to date.") true;
}
:if ([ $VersionToNum ($RouterBoard->"current-firmware") ] > [ $VersionToNum ($RouterBoard->"upgrade-firmware") ]) do={
  $LogPrintExit2 info $0 ("Different firmware version is available, but it is a downgrade. Ignoring.") true;
}

:if ([ /system/routerboard/settings/get auto-upgrade ] = false) do={
  $LogPrintExit2 info $0 ("Firmware version " . $RouterBoard->"upgrade-firmware" . \
    " is available, upgrading.") false;
  /system/routerboard/upgrade;
}

:while ([ :len [ /log/find where topics=({"system";"info";"critical"}) \
    message="Firmware upgraded successfully, please reboot for changes to take effect!" ] ] = 0) do={
  :delay 1s;
}

:local Uptime [ /system/resource/get uptime ];
:if ($Uptime < 1m) do={
  :delay $Uptime;
}

$LogPrintExit2 info $0 ("Firmware upgrade successful, rebooting.") false;
/system/reboot;