blob: a15f76602fc0928ac37fa6c44f1f3a8421ad7a86 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
#!rsc
# RouterOS script: email-backup
# Copyright (c) 2013-2019 Christian Hesse <mail@eworm.de>
#
# create and email backup and config file
:global Identity;
:global Domain;
:global EmailBackupTo;
:global EmailBackupCc;
:global BackupSendBinary;
:global BackupSendExport;
:global BackupCloud;
:global BackupPassword;
:if ($BackupSendBinary != true && \
$BackupSendExport != true && \
$BackupCloud != true) do={
:error ("Configured to send neither backup nor config export.");
}
# filename based on identity
:local FileName ($Identity . "." . $Domain);
:local CloudStatus $BackupCloud;
:local Attach [ :toarray "" ];
# get some system information
:local Model [ / system routerboard get model ];
:local SerialNumber [ / system routerboard get serial-number ];
:local Channel [ / system package update get channel ];
:local InstalledVersion [ / system package update get installed-version ];
# binary backup
:if ($BackupSendBinary = true || \
$BackupCloud = true) do={
/ system backup save encryption=aes-sha256 name=$FileName password=$BackupPassword;
# attach to mail
:if ($BackupSendBinary = true) do={
:set Attach ($Attach, ($FileName . ".backup"));
}
# upload to cloud
:if ($BackupCloud = true) do={
:do {
:if ([ / system backup cloud print count-only ] > 0) do={
/ system backup cloud remove-file [ find ];
}
/ system backup cloud upload-file action=upload src-file=($FileName . ".backup");
} on-error={
:set CloudStatus "failed";
}
}
}
# create configuration export
:if ($BackupSendExport = true) do={
/ export terse file=$FileName;
:set Attach ($Attach, ($FileName . ".rsc"));
}
# send email with status and files
/ tool e-mail send to=$EmailBackupTo cc=$EmailBackupCc \
subject=("[" . $Identity . "] Backup & Config") \
body=("Backup and config export for " . $Identity . ".\n\n" . \
"Routerboard: " . $Model . "\n" . \
"Serial number: " . $SerialNumber . "\n" . \
"Hostname: " . $Identity . "\n" . \
"Channel: " . $Channel . "\n" . \
"RouterOS: " . $InstalledVersion . "\n\n" . \
"Backup attached: " . $BackupSendBinary . "\n" . \
"Config attached: " . $BackupSendExport . "\n" . \
"Cloud backup: " . $CloudStatus) \
file=$Attach;
}
|