email-backup


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

#!rsc
# RouterOS script: email-backup
# Copyright (c) 2013-2018 Christian Hesse <mail@eworm.de>
#
# create and email backup and config file

:global "identity";
:global "domain";
:global "email-backup-to";
:global "email-backup-cc";
:global "backup-send-binary";
:global "backup-send-export";
:global "backup-password";

:if ($"backup-send-binary" = false && $"backup-send-export" = false) do={
  :error ("Configured to send neither backup nor config export.");
}

# filename based on identity
:local filename ($identity . "." . $domain);
:local attach [ :toarray "" ];

# get some system information
:local model [ / system routerboard get model ];
:local serialnumber [ / system routerboard get serial-number ];
:local channel [ / system package update get channel ];
:local installedversion [ / system package update get installed-version ];

# create binary backup
:if ($"backup-send-binary" = true) do={
  / system backup save name=$filename password=$"backup-password";
  / delay delay-time=10;
  :set attach ( $attach, ($filename . ".backup") );
}

# create configuration export
:if ($"backup-send-export" = true) do={
  / export terse file=$filename;
  / delay delay-time=10;
  :set attach ( $attach, ($filename . ".rsc") );
}

# email files
/ tool e-mail send to=$"email-backup-to" cc=$"email-backup-cc" \
    subject=("[" . $identity . "] Backup & Config") \
    body=("Backup and config export for " . $identity . ".\n\n" . \
      "Routerboard:     " . $model . "\n" . \
      "Serial number:   " . $serialnumber . "\n" . \
      "Hostname:        " . $identity . "\n" . \
      "Channel:         " . $channel . "\n" . \
      "RouterOS:        " . $installedversion . "\n\n" . \
      "Backup attached: " . $"backup-send-binary" . "\n" . \
      "Config attached: " . $"backup-send-export") \
    file=$attach;
}