collect-wireless-mac.template


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

#!rsc
# RouterOS script: collect-wireless-mac%TEMPL%
# Copyright (c) 2013-2019 Christian Hesse <mail@eworm.de>
#
# collect wireless mac adresses in access list
#
# !! This is just a template! Replace '%PATH%' with 'caps-man'
# !! or 'interface wireless'!

:global Identity;

:global GetMacVendor;
:global SendNotification;

:local PlaceBefore [ / %PATH% access-list find where comment="--- collected above ---" disabled ];
:if ([ :len $PlaceBefore ] = 0) do={
  :error "Missing disabled access-list entry with comment '--- collected above ---'";
}

:foreach RegTbl in=[ / %PATH% registration-table find ] do={
  :local Mac [ / %PATH% registration-table get $RegTbl mac-address ];
  :local AccessList [ :pick [ / %PATH% access-list find where mac-address=$Mac ] 0 ];
  :if ([ :len $AccessList ] = 0) do={
    :local HostName "no dhcp lease";
    :local Address "no dhcp lease";
    :local Lease [ / ip dhcp-server lease find where mac-address=$Mac ];
    :if ([ :len $Lease ] > 0) do={
      :set HostName [ / ip dhcp-server lease get $Lease host-name ];
      :set Address [ / ip dhcp-server lease get $Lease address ];
    }
    :if ([ :len $HostName ] = 0) do={
      :set HostName "no hostname";
    }
    :if ([ :len $Address ] = 0) do={
      :set Address "no address";
    }
    :local RegEntry [ / %PATH% registration-table find where mac-address=$Mac ];
    :local Interface [ / %PATH% registration-table get $RegEntry interface ];
    :local Ssid [ / caps-man registration-table get $RegEntry ssid ];
    :local Ssid [ / interface wireless get [ find where name=$Interface ] ssid ];
    :local DateTime ([ / system clock get date ] . " " . [ / system clock get time ]);
    :local Vendor [ $GetMacVendor $Mac ];
    :local Message ("unknown MAC address " . $Mac . " (" . $Vendor . ", " . $HostName . ") " . \
      "first seen on " . $DateTime . " connected to SSID " . $Ssid . ", interface " . $Interface);
    / log info $Message;
    / %PATH% access-list add place-before=$PlaceBefore comment=$Message mac-address=$Mac disabled=yes;
    $SendNotification ($Mac . " connected to " . $Ssid) \
      ("A device with unknown MAC address connected to " . $Ssid . " on " . $Identity . ".\n\n" . \
        "Controller: " . $Identity . "\n" . \
        "Interface:  " . $Interface . "\n" . \
        "SSID:       " . $Ssid . "\n" . \
        "MAC:        " . $Mac . "\n" . \
        "Vendor:     " . $Vendor . "\n" . \
        "Hostname:   " . $HostName . "\n" . \
        "Address:    " . $Address . "\n" . \
        "Date:       " . $DateTime);
  } else={
    :local Comment [ / %PATH% access-list get $AccessList comment ];
    :log debug ("MAC address " . $Mac . " already known: " . $Comment);
  }
}