capsman-rolling-upgrade


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27

#!rsc
# RouterOS script: capsman-rolling-upgrade
# Copyright (c) 2018-2020 Christian Hesse <mail@eworm.de>
#                         Michael Gisbers <michael@gisbers.de>
#
# upgrade CAPs one after another
# https://git.eworm.de/cgit/routeros-scripts/about/doc/capsman-rolling-upgrade.md

:global LogPrintExit;
:global ScriptLock;

$ScriptLock "capsman-rolling-upgrade";

:local InstalledVersion [ / system package update get installed-version ];

:local RemoteCapCount [ /caps-man remote-cap print count-only ];
:if ($RemoteCapCount > 0) do={
  :local Delay (600 / $RemoteCapCount);
  :if ($Delay > 120) do={ :set Delay 120; }
  :foreach RemoteCap in=[ / caps-man remote-cap find where version!=$InstalledVersion ] do={
    :local RemoteCapVal [ / caps-man remote-cap get $RemoteCap ];
    $LogPrintExit info ("Starting upgrade for " . $RemoteCapVal->"name" . \
        " (" . $RemoteCapVal->"identity" . ")...") false;
    / caps-man remote-cap upgrade [ find where name=$RemoteCapVal->"name" ];
    :delay ($Delay . "s");
  }
}