From a832fd04ef085ef7e85000843a8e8fa59ce36dfb Mon Sep 17 00:00:00 2001
From: Christian Hesse <mail@eworm.de>
Date: Tue, 7 Mar 2023 10:57:42 +0100
Subject: rename scripts and add file extension ".rsc"

No functional change for the user... The migration is done
automatically.
---
 unattended-lte-firmware-upgrade.rsc | 45 +++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 unattended-lte-firmware-upgrade.rsc

(limited to 'unattended-lte-firmware-upgrade.rsc')

diff --git a/unattended-lte-firmware-upgrade.rsc b/unattended-lte-firmware-upgrade.rsc
new file mode 100644
index 0000000..eac65c3
--- /dev/null
+++ b/unattended-lte-firmware-upgrade.rsc
@@ -0,0 +1,45 @@
+#!rsc by RouterOS
+# RouterOS script: unattended-lte-firmware-upgrade
+# Copyright (c) 2018-2023 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+#
+# schedule unattended lte firmware upgrade
+# https://git.eworm.de/cgit/routeros-scripts/about/doc/unattended-lte-firmware-upgrade.md
+
+:foreach Interface in=[ /interface/lte/find where running ] do={
+  :local Firmware;
+  :local IntName [ /interface/lte/get $Interface name ];
+  :do {
+    :set Firmware [ /interface/lte/firmware-upgrade $Interface once as-value ];
+  } on-error={
+    :log debug ("Could not get latest LTE firmware version for interface " . $IntName . ".");
+  }
+
+  :if ([ :typeof $Firmware ] = "array") do={
+    :if (($Firmware->"installed") != ($Firmware->"latest")) do={
+      :log info ("Scheduling LTE firmware upgrade for interface " . $IntName . ".");
+
+      :global LTEFirmwareUpgrade do={
+        :global LTEFirmwareUpgrade;
+        :set LTEFirmwareUpgrade;
+
+        /system/scheduler/remove ($1 . "-firmware-upgrade");
+        /interface/lte/firmware-upgrade $1 upgrade=yes;
+        :log info ("LTE firmware upgrade on '" . $1 . "' finished, waiting for reset.");
+        :delay 240s;
+        :local Firmware [ /interface/lte/firmware-upgrade $1 once as-value ];
+        :if (($Firmware->"installed") != ($Firmware->"latest")) do={
+          :log warning ("LTE firmware versions still differ. Resetting again...");
+          /interface/lte/at-chat $1 input="AT+RESET";
+        }
+      }
+
+      /system/scheduler/add name=($IntName . "-firmware-upgrade") start-time=startup interval=2s \
+        on-event=(":global LTEFirmwareUpgrade; \$LTEFirmwareUpgrade \"" . $IntName . "\";");
+    } else={
+      :log info ("The LTE firmware is up to date on interface " . $IntName . ".");
+    }
+  } else={
+    :log info ("No LTE firmware information available for interface " . $IntName . ".");
+  }
+}
-- 
cgit v1.2.3-54-g00ecf