From 012db05a9350311ddac85a95e487d4fc0ebabcb6 Mon Sep 17 00:00:00 2001
From: Christian Hesse <mail@eworm.de>
Date: Fri, 17 Sep 2021 16:32:59 +0200
Subject: global-functions: move $ScriptRunOnce to optional module

---
 global-functions.d/scriptrunonce | 46 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 global-functions.d/scriptrunonce

(limited to 'global-functions.d')

diff --git a/global-functions.d/scriptrunonce b/global-functions.d/scriptrunonce
new file mode 100644
index 0000000..ce9425b
--- /dev/null
+++ b/global-functions.d/scriptrunonce
@@ -0,0 +1,46 @@
+#!rsc by RouterOS
+# RouterOS script: global-functions.d/scriptrunonece
+# Copyright (c) 2020-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+
+:global ScriptRunOnce;
+
+# fetch and run script(s) once
+:set ScriptRunOnce do={
+  :local Scripts [ :toarray $1 ];
+
+  :global ScriptRunOnceBaseUrl;
+  :global ScriptRunOnceUrlSuffix;
+
+  :global LogPrintExit2;
+  :global ValidateSyntax;
+
+  :foreach Script in=$Scripts do={
+    :if (!($Script ~ "^(ftp|https\?|sftp)://")) do={
+      :if ([ :len $ScriptRunOnceBaseUrl ] = 0) do={
+        $LogPrintExit2 warning $0 ("Script '" . $Script . "' is not an url and base url is not available.") true;
+      }
+      :set Script ($ScriptRunOnceBaseUrl . $Script . $ScriptRunOnceUrlSuffix);
+    }
+
+    :local Source;
+    :do {    
+      :set Source ([ / tool fetch check-certificate=yes-without-crl $Script output=user as-value ]->"data");
+    } on-error={
+      $LogPrintExit2 warning $0 ("Failed fetching script '" . $Script . "'!") false;
+    }
+
+    :if ([ :len $Source ] > 0) do={
+      :if ([ $ValidateSyntax $Source ] = true) do={
+        :do {
+          $LogPrintExit2 info $0 ("Running script '" . $Script . "' now.") false;
+          [ :parse $Source ];
+        } on-error={
+          $LogPrintExit2 warning $0 ("The script '" . $Script . "' failed to run!") false;
+        }
+      } else={
+        $LogPrintExit2 warning $0 ("The script '" . $Script . "' failed syntax validation!") false;
+      }
+    }
+  }
+}
-- 
cgit v1.2.3-54-g00ecf