From 9295d06fe2fce058b6b21d69ea6eac8282d23337 Mon Sep 17 00:00:00 2001
From: Christian Hesse <mail@eworm.de>
Date: Mon, 20 Sep 2021 13:19:34 +0200
Subject: global-functions.d/inspectvar: add $InspectVar...

to inspect variables. This is useful for variables with (nested) arrays,
for example inspecting $NetwatchNotify (from netwatch-notify):

[admin@Mikrotik] > $InspectVar $NetwatchNotify
-type-> array
  -key-> quad-one
    -type-> array
      -key-> count
        -type-> num
        -value-> 0
      -key-> notified
        -type-> bool
        -value-> false
      -key-> parent
        -type-> nothing
      -key-> resolve-failed
        -type-> nothing
      -key-> since
        -type-> nothing
  -key-> example.com
    -type-> array
      -key-> count
        -type-> num
        -value-> 0
      -key-> notified
        -type-> bool
        -value-> false
      -key-> parent
        -type-> str
        -value-> quad-one
      -key-> resolve-failed
        -type-> nothing
      -key-> since
        -type-> nothing
---
 global-functions.d/inspectvar | 40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 global-functions.d/inspectvar

(limited to 'global-functions.d/inspectvar')

diff --git a/global-functions.d/inspectvar b/global-functions.d/inspectvar
new file mode 100644
index 0000000..15da04a
--- /dev/null
+++ b/global-functions.d/inspectvar
@@ -0,0 +1,40 @@
+#!rsc by RouterOS
+# RouterOS script: global-functions.d/inspectvar
+# Copyright (c) 2020-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+
+:global InspectVar;
+
+# inspect variable
+:set InspectVar do={
+  :local Input $1;
+  :local Level (0 + [ :tonum $2 ]);
+
+  :global InspectVar;
+
+  :local PutIndent do={
+    :local Prefix [ :tostr $1 ];
+    :local Value  [ :tostr $2 ];
+    :local Level  [ :tonum $3 ];
+
+    :local Indent "";
+    :for I from=1 to=$Level step=1 do={
+      :set Indent ($Indent . "  ");
+    }
+    :put ($Indent . "-" . $Prefix . "-> " . $Value);
+  }
+
+  :local TypeOf [ :typeof $Input ];
+  $PutIndent "type" $TypeOf $Level;
+  
+  :if ($TypeOf = "array") do={
+    :foreach Key,Value in=$Input do={
+      $PutIndent "key" $Key ($Level + 1);
+      $InspectVar $Value ($Level + 2);
+    }
+  } else={
+    :if ($TypeOf != "nothing") do={
+      $PutIndent "value" $Input $Level;
+    }
+  }
+}
-- 
cgit v1.2.3-54-g00ecf