From 5101d57d52e60a3c10b974217af70166a3145c45 Mon Sep 17 00:00:00 2001
From: Christian Hesse <mail@eworm.de>
Date: Fri, 14 Jun 2019 14:59:49 +0200
Subject: backup: split off cloud-backup

Currently backup to MikroTik cloud is pretty unreliable and script can
not catch errors at runtime. Looks like this does not change any time
soon (Ticket#2019052022003204).

So let's just split off the cloud backup to make sure email backup works
as expected.
---
 cloud-backup | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 cloud-backup

(limited to 'cloud-backup')

diff --git a/cloud-backup b/cloud-backup
new file mode 100644
index 0000000..f9e7747
--- /dev/null
+++ b/cloud-backup
@@ -0,0 +1,42 @@
+#!rsc
+# RouterOS script: cloud-backup
+# Copyright (c) 2013-2019 Christian Hesse <mail@eworm.de>
+#
+# upload backup to MikroTik cloud
+
+:global Identity;
+:global BackupPassword;
+
+:global SendNotification;
+
+# get some system information
+:local BoardName [ / system resource get board-name ];
+:local Model [ / system routerboard get model ];
+:local SerialNumber [ / system routerboard get serial-number ];
+:local Channel [ / system package update get channel ];
+:local InstalledVersion [ / system package update get installed-version ];
+
+:do {
+  # we are not interested in output, but print without count-only is
+  # required to fetch information from cloud
+  / system backup cloud print as-value;
+  :if ([ / system backup cloud print count-only ] > 0) do={
+    / system backup cloud remove-file ([ find ]->0);
+  }
+  / system backup cloud upload-file action=create-and-upload password=$BackupPassword;
+  :local Cloud [ / system backup cloud get ([ find ]->0) ];
+
+  $SendNotification "Cloud backup" \
+    ("Uploaded backup for " . $Identity . " to cloud.\n\n" . \
+      "Board name:     " . $BoardName . "\n" . \
+      "Model:          " . $Model . "\n" . \
+      "Serial number:  " . $SerialNumber . "\n" . \
+      "Hostname:       " . $Identity . "\n" . \
+      "Channel:        " . $Channel . "\n" . \
+      "RouterOS:       " . $InstalledVersion . "\n\n" . \
+      "Name:           " . $Cloud->"name" . "\n" . \
+      "Size:           " . $Cloud->"size" . "\n" . \
+      "Download key:   " . $Cloud->"secret-download-key");
+} on-error={
+  :log error ("Failed uploading backup for " . $Identity . " to cloud.");
+}
-- 
cgit v1.2.3-54-g00ecf