From 29dc1b884154d14b45ebf7471f59ec0755bab549 Mon Sep 17 00:00:00 2001
From: Christian Hesse <mail@eworm.de>
Date: Tue, 27 Aug 2019 10:35:53 +0200
Subject: add script 'check-health'

This may be incomplete... Please report if you have missing PSUs,
ttemperature sensors, whatever.
---
 check-health          | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++
 global-config         | 10 ++++++++-
 global-config.changes |  5 +++--
 global-functions      |  2 +-
 4 files changed, 70 insertions(+), 4 deletions(-)
 create mode 100644 check-health

diff --git a/check-health b/check-health
new file mode 100644
index 0000000..b69ae4a
--- /dev/null
+++ b/check-health
@@ -0,0 +1,57 @@
+#!rsc
+# RouterOS script: check-health
+# Copyright (c) 2019 Christian Hesse <mail@eworm.de>
+#
+# check for RouterOS health state
+
+:global CheckHealthLast;
+:global CheckHealthTemperature;
+:global Identity;
+
+:global SendNotification;
+
+:local FormatVoltage do={
+  :local Voltage [ :tonum $1 ];
+  :return (($Voltage / 10) . "." . ($Voltage % ($Voltage / 10 * 10)) . "V");
+}
+
+:local CheckHealthCurrent [ / system health get ];
+
+:foreach Voltage in={ "psu1-voltage"; "psu2-voltage"; "voltage" } do={
+  :if ([ :typeof ($CheckHealthLast->$Voltage) ] = "num" && \
+       [ :typeof ($CheckHealthCurrent->$Voltage) ] = "num") do={
+    :if ($CheckHealthLast->$Voltage * 115 / 100 < $CheckHealthCurrent->$Voltage || \
+         $CheckHealthLast->$Voltage * 100 / 115 > $CheckHealthCurrent->$Voltage) do={
+      $SendNotification ("Health warning: " . $Voltage) \
+          ("The " . $Voltage . " on " . $Identity . " jumped more than 15%.\n\n" . \
+          "old value: " . [ $FormatVoltage ($CheckHealthLast->$Voltage) ] . "\n" . \
+          "new value: " . [ $FormatVoltage ($CheckHealthCurrent->$Voltage) ]);
+    }
+  }
+}
+
+:foreach PSU in={ "psu1"; "psu2" } do={
+  :if ($CheckHealthLast->($PSU . "-state") = "ok" && \
+       $CheckHealthCurrent->($PSU . "-state") != "ok") do={
+    $SendNotification ("Health warning: " . $PSU . " state") \
+        ("The power supply unit '" . $PSU . "' on " . $Identity . " failed!");
+  }
+}
+
+:foreach Temperature in={ "temperature"; "cpu-temperature"; "board-temperature1"; "board-temperature2" } do={
+  :if ([ :typeof ($CheckHealthLast->$Temperature) ] = "num" && \
+       [ :typeof ($CheckHealthCurrent->$Temperature) ] = "num") do={
+    :if ([ :typeof ($CheckHealthTemperature->$Temperature) ] != "num" ) do={
+      :log warning ("No threshold given for " . $Temperature . ", assuming 50C.");
+      :set ($CheckHealthTemperature->$Temperature) 50;
+    }
+    :if ($CheckHealthLast->$Temperature <= $CheckHealthTemperature->$Temperature && \
+         $CheckHealthCurrent->$Temperature > $CheckHealthTemperature->$Temperature) do={
+      $SendNotification ("Health warning: " . $Temperature) \
+          ("The " . $Temperature . " on " . $Identity . " is above threshold: " .  \
+          $CheckHealthCurrent->$Temperature . "C");
+    }
+  }
+}
+
+:set CheckHealthLast $CheckHealthCurrent;
diff --git a/global-config b/global-config
index b14ff6e..e8fd04d 100644
--- a/global-config
+++ b/global-config
@@ -6,7 +6,7 @@
 
 # Make sure all configuration properties are up to date and this
 # value is in sync with value in script 'global-functions'!
-:global GlobalConfigVersion 6;
+:global GlobalConfigVersion 7;
 
 # This is used for DNS and backup file.
 :global Domain "example.com";
@@ -44,6 +44,14 @@
 :global SafeUpdateUrl "";
 #:global SafeUpdateUrl "https://example.com/ros/safe-update/";
 
+# These thresholds control when to send notification on temperature.
+:global CheckHealthTemperature {
+  temperature=50;
+  cpu-temperature=70;
+  board-temperature1=50;
+  board-temperature2=50;
+}
+
 # This controls what configuration is activated by bridge-port-to-default.
 :global BridgePortTo "default";
 
diff --git a/global-config.changes b/global-config.changes
index 656cb7f..6123855 100644
--- a/global-config.changes
+++ b/global-config.changes
@@ -3,10 +3,11 @@
 
 # Changes for global-config to be added to notification on script-updates
 :global GlobalConfigChanges {
-  1="moved variables from global-config to global-functions for independence";
+  1="moved variables from 'global-config' to 'global-functions' for independence";
   2="variable names became CamelCase to work around scripting issues";
   3="variable for certificate renew passphrase became an array to support multiple passphrases";
   4="added option to ignore global-config changes";
-  5="split off new script cloud-backup from email-backup";
+  5="split off new script 'cloud-backup' from 'email-backup'";
   6="introduced script 'upload-backup' with new configuration parameters";
+  7="introduced script 'check-health' with new configuration parameters";
 };
diff --git a/global-functions b/global-functions
index 2e4d43c..c5e63c4 100644
--- a/global-functions
+++ b/global-functions
@@ -5,7 +5,7 @@
 # global functions
 
 # expected configuration version
-:global ExpectedConfigVersion 6;
+:global ExpectedConfigVersion 7;
 
 # global variables not to be changed by user
 :global SentConfigChangesNotification "-";
-- 
cgit v1.2.3-54-g00ecf