shorten modules directory name (global-functions.d -> mod)change-67

7 files changed, 558 insertions, 0 deletions

diff --git a/mod/bridge-port-to b/mod/bridge-port-to
new file mode 100644
index 0000000..40b216c
--- /dev/null
+++ b/mod/bridge-port-to
@@ -0,0 +1,54 @@
+#!rsc by RouterOS
+# RouterOS script: mod/bridge-port-to
+# Copyright (c) 2013-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+#
+# reset bridge ports to default bridge
+# https://git.eworm.de/cgit/routeros-scripts/about/doc/mod/bridge-port-to.md
+
+:global BridgePortTo;
+
+:set BridgePortTo do={
+  :local BridgePortTo [ :tostr $1 ];
+
+  :global IfThenElse;
+  :global LogPrintExit2;
+  :global ParseKeyValueStore;
+
+  :foreach BridgePort in=[ / interface bridge port find where !(comment=[]) ] do={
+    :local BridgePortVal [ / interface bridge port get $BridgePort ];
+    :foreach Config,BridgeDefault in=[ $ParseKeyValueStore ($BridgePortVal->"comment") ] do={
+      :if ($Config = $BridgePortTo) do={
+        :local DHCPClient [ / ip dhcp-client find where interface=$BridgePortVal->"interface" comment="toggle with bridge port" ];
+
+        :if ($BridgeDefault = "dhcp-client") do={
+          :if ([ :len $DHCPClient ] != 1) do={
+            $LogPrintExit2 warning $0 ([ $IfThenElse ([ :len $DHCPClient ] = 0) "Missing" "Duplicate" ] . \
+                " dhcp client configuration for interface " . $BridgePortVal->"interface" . "!") true;
+          }
+          :local DHCPClientDisabled [ / ip dhcp-client get $DHCPClient disabled ];
+
+          :if ($BridgePortVal->"disabled" = false || $DHCPClientDisabled = true) do={
+            $LogPrintExit2 info $0 ("Disabling bridge port for interface " . $BridgePortVal->"interface" . ", enabling dhcp client.") false;
+            / interface bridge port disable $BridgePort;
+            :delay 200ms;
+            / ip dhcp-client enable $DHCPClient;
+          }
+        } else={
+          :if ($BridgePortVal->"disabled" = true || $BridgeDefault != $BridgePortVal->"bridge") do={
+            $LogPrintExit2 info $0 ("Enabling bridge port for interface " . $BridgePortVal->"interface" . ", changing to " . $BridgePortTo . \
+                " bridge " . $BridgeDefault . ", disabling dhcp client.") false;
+            :if ([ :len $DHCPClient ] = 1) do={
+              / ip dhcp-client disable $DHCPClient;
+              :delay 200ms;
+            }
+            / interface bridge port set disabled=no bridge=$BridgeDefault $BridgePort;
+          } else={
+            $LogPrintExit2 debug $0 ("Interface " . $BridgePortVal->"interface" . " already connected to " . $BridgePortTo . \
+                " bridge " . $BridgeDefault . ".") false;
+          }
+        }
+      }
+    }
+  }
+}
diff --git a/mod/bridge-port-vlan b/mod/bridge-port-vlan
new file mode 100644
index 0000000..bfe00e9
--- /dev/null
+++ b/mod/bridge-port-vlan
@@ -0,0 +1,62 @@
+#!rsc by RouterOS
+# RouterOS script: mod/bridge-port-vlan
+# Copyright (c) 2013-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+#
+# manage VLANs on bridge ports
+# https://git.eworm.de/cgit/routeros-scripts/about/doc/mod/bridge-port-vlan.md
+
+:global BridgePortVlan;
+
+# TODO
+:global BridgePortVlan do={
+  :local ConfigTo [ :tostr $1 ];
+
+  :global IfThenElse;
+  :global LogPrintExit2;
+  :global ParseKeyValueStore;
+
+  :foreach BridgePort in=[ / interface bridge port find where !(comment=[]) ] do={
+    :local BridgePortVal [ / interface bridge port get $BridgePort ];
+    :foreach Config,Vlan in=[ $ParseKeyValueStore ($BridgePortVal->"comment") ] do={
+      :if ($Config = $ConfigTo) do={
+        :local DHCPClient [ / ip dhcp-client find where interface=$BridgePortVal->"interface" comment="toggle with bridge port" ];
+
+        :if ($Vlan = "dhcp-client") do={
+          :if ([ :len $DHCPClient ] != 1) do={
+            $LogPrintExit2 warning $0 ([ $IfThenElse ([ :len $DHCPClient ] = 0) "Missing" "Duplicate" ] . \
+                " dhcp client configuration for interface " . $BridgePortVal->"interface" . "!") true;
+          }
+          :local DHCPClientDisabled [ / ip dhcp-client get $DHCPClient disabled ];
+
+          :if ($BridgePortVal->"disabled" = false || $DHCPClientDisabled = true) do={
+            $LogPrintExit2 info $0 ("Disabling bridge port for interface " . $BridgePortVal->"interface" . ", enabling dhcp client.") false;
+            / interface bridge port disable $BridgePort;
+            :delay 200ms;
+            / ip dhcp-client enable $DHCPClient;
+          }
+        } else={
+          :if ($Vlan != [ :tostr [ :tonum $Vlan ] ]) do={
+            :do {
+              :set $Vlan ([ / interface bridge vlan get [ find where comment=$Vlan ] vlan-ids ]->0);
+            } on-error={
+              $LogPrintExit2 warning $0 ("Could not find VLAN '" . $Vlan . "' for interface " . $BridgePortVal->"interface" . "!") true;
+            }
+          }
+          :if ($BridgePortVal->"disabled" = true || $Vlan != $BridgePortVal->"pvid") do={
+            $LogPrintExit2 info $0 ("Enabling bridge port for interface " . $BridgePortVal->"interface" . ", changing to " . $ConfigTo . \
+                " vlan " . $Vlan . ", disabling dhcp client.") false;
+            :if ([ :len $DHCPClient ] = 1) do={
+              / ip dhcp-client disable $DHCPClient;
+              :delay 200ms;
+            }
+            / interface bridge port set disabled=no pvid=$Vlan $BridgePort;
+          } else={
+            $LogPrintExit2 debug $0 ("Interface " . $BridgePortVal->"interface" . " already connected to " . $ConfigTo . \
+                " vlan " . $Vlan . ".") false;
+          }
+        }
+      }
+    }
+  }
+}
diff --git a/mod/inspectvar b/mod/inspectvar
new file mode 100644
index 0000000..4e10fd6
--- /dev/null
+++ b/mod/inspectvar
@@ -0,0 +1,40 @@
+#!rsc by RouterOS
+# RouterOS script: mod/inspectvar
+# Copyright (c) 2020-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+
+:global InspectVar;
+
+# inspect variable
+:set InspectVar do={
+  :local Input $1;
+  :local Level (0 + [ :tonum $2 ]);
+
+  :global InspectVar;
+
+  :local PutIndent do={
+    :local Prefix [ :tostr $1 ];
+    :local Value  [ :tostr $2 ];
+    :local Level  [ :tonum $3 ];
+
+    :local Indent "";
+    :for I from=1 to=$Level step=1 do={
+      :set Indent ($Indent . "  ");
+    }
+    :put ($Indent . "-" . $Prefix . "-> " . $Value);
+  }
+
+  :local TypeOf [ :typeof $Input ];
+  $PutIndent "type" $TypeOf $Level;
+  
+  :if ($TypeOf = "array") do={
+    :foreach Key,Value in=$Input do={
+      $PutIndent "key" $Key ($Level + 1);
+      $InspectVar $Value ($Level + 2);
+    }
+  } else={
+    :if ($TypeOf != "nothing") do={
+      $PutIndent "value" $Input $Level;
+    }
+  }
+}
diff --git a/mod/ipcalc b/mod/ipcalc
new file mode 100644
index 0000000..64a03a9
--- /dev/null
+++ b/mod/ipcalc
@@ -0,0 +1,35 @@
+#!rsc by RouterOS
+# RouterOS script: mod/ipcalc
+# Copyright (c) 2020-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+
+:global IPCalc;
+
+# calculate and print netmask, network, min host, max host and broadcast
+:set IPCalc do={
+  :local Input [ :tostr $1 ];
+  :local Address [ :toip [ :pick $Input 0 [ :find $Input "/" ] ] ];
+  :local Bits [ :tonum [ :pick $Input ([ :find $Input "/" ] + 1) [ :len $Input ] ] ];
+  :local Mask ((255.255.255.255 << (32 - $Bits)) & 255.255.255.255);
+
+  :local Return {
+    "address"=$Address;
+    "netmask"=$Mask;
+    "networkaddress"=($Address & $Mask);
+    "networkbits"=$Bits;
+    "network"=(($Address & $Mask) . "/" . $Bits);
+    "hostmin"=(($Address & $Mask) | 0.0.0.1);
+    "hostmax"=(($Address | ~$Mask) ^ 0.0.0.1);
+    "broadcast"=($Address | ~$Mask);
+  }
+
+  :put ( \
+    "Address:   " . $Return->"address" . "\n\r" . \
+    "Netmask:   " . $Return->"netmask" . "\n\r" . \
+    "Network:   " . $Return->"network" . "\n\r" . \
+    "HostMin:   " . $Return->"hostmin" . "\n\r" . \
+    "HostMax:   " . $Return->"hostmax" . "\n\r" . \
+    "Broadcast: " . $Return->"broadcast");
+
+  :return $Return;
+}
diff --git a/mod/notification-matrix b/mod/notification-matrix
new file mode 100644
index 0000000..a78539f
--- /dev/null
+++ b/mod/notification-matrix
@@ -0,0 +1,157 @@
+#!rsc by RouterOS
+# RouterOS script: mod/notification-matrix
+# Copyright (c) 2013-2021 Michael Gisbers <michael@gisbers.de>
+#                         Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+
+:global FlushMatrixQueue;
+:global NotificationFunctions;
+:global SendMatrix;
+:global SendMatrix2;
+
+# flush Matrix queue
+:set FlushMatrixQueue do={
+  :global MatrixQueue;
+
+  :global LogPrintExit2;
+
+  :local AllDone true;
+  :local QueueLen [ :len $MatrixQueue ];
+
+  :if ([ :len [ / system scheduler find where name="FlushMatrixQueue" ] ] > 0 && $QueueLen = 0) do={
+    $LogPrintExit2 warning $0 ("Flushing Matrix messages from scheduler, but queue is empty.") false;
+  }
+
+  :foreach Id,Message in=$MatrixQueue do={
+    :if ([ :typeof $Message ] = "array" ) do={
+      :do {
+        / tool fetch check-certificate=yes-without-crl output=none http-method=post \
+          ("https://" . $Message->"homeserver" . "/_matrix/client/r0/rooms/" . $Message->"room" . \
+           "/send/m.room.message?access_token=" . $Message->"accesstoken") \
+          http-data=("{ \"msgtype\": \"m.text\", \"body\": \"" . $Message->"plain" . "\"," . \
+           "\"format\": \"org.matrix.custom.html\", \"formatted_body\": \"" . \
+           $Message->"formatted" . "\" }") as-value;
+        :set ($MatrixQueue->$Id);
+      } on-error={
+        $LogPrintExit2 debug $0 ("Sending queued Matrix message failed.") false;
+        :set AllDone false;
+      }
+    }
+  }
+
+  :if ($AllDone = true && $QueueLen = [ :len $MatrixQueue ]) do={
+    / system scheduler remove [ find where name="FlushMatrixQueue" ];
+    :set MatrixQueue;
+  }
+}
+
+# send notification via Matrix - expects one array argument
+:set ($NotificationFunctions->"matrix") do={
+  :local Notification $1;
+
+  :global Identity;
+  :global MatrixAccessToken;
+  :global MatrixAccessTokenOverride;
+  :global MatrixHomeServer;
+  :global MatrixHomeServerOverride;
+  :global MatrixQueue;
+  :global MatrixRoom;
+  :global MatrixRoomOverride;
+
+  :global EitherOr;
+  :global LogPrintExit2;
+  :global SymbolForNotification;
+
+  :local PrepareText do={
+    :local Input [ :tostr $1 ];
+
+    :if ([ :len $Input ] = 0) do={
+      :return "";
+    }
+
+    :local Return "";
+    :local Chars {
+      "plain"={ "\\"; "\""; "\n" };
+      "format"={ "\\"; "\""; "\n"; "&"; "<"; ">" };
+    }
+    :local Subs {
+      "plain"={ "\\\\"; "\\\""; "\\n" };
+      "format"={ "\\\\"; "&quot;"; "<br/>"; "&amp;"; "&lt;"; "&gt;" };
+    }
+
+    :for I from=0 to=([ :len $Input ] - 1) do={
+      :local Char [ :pick $Input $I ];
+      :local Replace [ :find ($Chars->$2) $Char ];
+
+      :if ([ :typeof $Replace ] = "num") do={
+        :set Char ($Subs->$2->$Replace);
+      }
+      :set Return ($Return . $Char);
+    }
+
+    :return $Return;
+  }
+
+  :local AccessToken [ $EitherOr ($MatrixAccessTokenOverride->($Notification->"origin")) $MatrixAccessToken ];
+  :local HomeServer [ $EitherOr ($MatrixHomeServerOverride->($Notification->"origin")) $MatrixHomeServer ];
+  :local Room [ $EitherOr ($MatrixRoomOverride->($Notification->"origin")) $MatrixRoom ];
+
+  :if ([ :len $AccessToken ] = 0 || [ :len $HomeServer ] = 0 || [ :len $Room ] = 0) do={
+    :return false;
+  }
+
+  :local Plain [ $PrepareText ("## [" . $Identity . "] " . ($Notification->"subject") . "\n```\n" . \
+    ($Notification->"message") . "\n```") "plain" ];
+  :local Formatted ("<h2>" . [ $PrepareText ("[" . $Identity . "] " . ($Notification->"subject")) "format" ] . "</h2>" . \
+    "<pre><code>" . [ $PrepareText ($Notification->"message") "format" ] . "</code></pre>");
+  :if ([ :len ($Notification->"link") ] > 0) do={
+    :set Plain ($Plain . "\\n" . [ $SymbolForNotification "link" ] . \
+      [ $PrepareText ("[" . $Notification->"link" . "](" . $Notification->"link" . ")") "plain" ]);
+    :set Formatted ($Formatted . "<br/>" . [ $SymbolForNotification "link" ] . \
+      "<a href=\\\"" . [ $PrepareText ($Notification->"link") "format" ] . "\\\">" . \
+      [ $PrepareText ($Notification->"link") "format" ] . "</a>");
+  }
+
+  :do {
+    / tool fetch check-certificate=yes-without-crl output=none http-method=post \
+      ("https://" . $HomeServer . "/_matrix/client/r0/rooms/" . $Room . \
+       "/send/m.room.message?access_token=" . $AccessToken) \
+      http-data=("{ \"msgtype\": \"m.text\", \"body\": \"" . $Plain . "\"," . \
+       "\"format\": \"org.matrix.custom.html\", \"formatted_body\": \"" . \
+       $Formatted . "\" }") as-value;
+  } on-error={
+    $LogPrintExit2 info $0 ("Failed sending Matrix notification! Queuing...") false;
+
+    :if ([ :typeof $MatrixQueue ] = "nothing") do={
+      :set MatrixQueue [ :toarray "" ];
+    }
+    :local Text ([ $SymbolForNotification "alarm-clock" ] . \
+      "This message was queued since " . [ / system clock get date ] . \
+      " " . [ / system clock get time ] . " and may be obsolete.");
+    :set Plain ($Plain . "\\n" . $Text);
+    :set Formatted ($Formatted . "<br/>" . $Text);
+    :set ($MatrixQueue->[ :len $MatrixQueue ]) { room=$Room; \
+      accesstoken=$AccessToken; homeserver=$HomeServer; \
+      plain=$Plain; formatted=$Formatted };
+    :if ([ :len [ / system scheduler find where name="FlushMatrixQueue" ] ] = 0) do={
+      / system scheduler add name=FlushMatrixQueue interval=1m start-time=startup \
+        on-event=(":global FlushMatrixQueue; \$FlushMatrixQueue;");
+    }
+  }
+}
+
+# send notification via Matrix - expects at lease two string arguments
+:set SendMatrix do={
+  :global SendMatrix2;
+
+  $SendMatrix2 ({ subject=$1; message=$2; link=$3 });
+}
+
+# send notification via Matrix - expects one array argument
+:set SendMatrix2 do={
+  :local Notification $1;
+
+  :global NotificationFunctions;
+
+  ($NotificationFunctions->"matrix") ("\$NotificationFunctions->\"matrix\"") $Notification;
+}
diff --git a/mod/notification-telegram b/mod/notification-telegram
new file mode 100644
index 0000000..d575103
--- /dev/null
+++ b/mod/notification-telegram
@@ -0,0 +1,164 @@
+#!rsc by RouterOS
+# RouterOS script: mod/notification-telegram
+# Copyright (c) 2013-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+
+:global FlushTelegramQueue;
+:global NotificationFunctions;
+:global SendTelegram;
+:global SendTelegram2;
+
+# flush telegram queue
+:set FlushTelegramQueue do={
+  :global TelegramQueue;
+
+  :global LogPrintExit2;
+
+  :local AllDone true;
+  :local QueueLen [ :len $TelegramQueue ];
+
+  :if ([ :len [ / system scheduler find where name="FlushTelegramQueue" ] ] > 0 && $QueueLen = 0) do={
+    $LogPrintExit2 warning $0 ("Flushing Telegram messages from scheduler, but queue is empty.") false;
+  }
+
+  :foreach Id,Message in=$TelegramQueue do={
+    :if ([ :typeof $Message ] = "array" ) do={
+      :do {
+        / tool fetch check-certificate=yes-without-crl output=none http-method=post \
+          ("https://api.telegram.org/bot" . ($Message->"tokenid") . "/sendMessage") \
+          http-data=("chat_id=" . ($Message->"chatid") . \
+          "&disable_notification=" . ($Message->"silent") . \
+          "&disable_web_page_preview=true&parse_mode=" . ($Message->"parsemode") . \
+          "&text=" . ($Message->"text")) as-value;
+        :set ($TelegramQueue->$Id);
+      } on-error={
+        $LogPrintExit2 debug $0 ("Sending queued Telegram message failed.") false;
+        :set AllDone false;
+      }
+    }
+  }
+
+  :if ($AllDone = true && $QueueLen = [ :len $TelegramQueue ]) do={
+    / system scheduler remove [ find where name="FlushTelegramQueue" ];
+    :set TelegramQueue;
+  }
+}
+
+# send notification via telegram - expects one array argument
+:set ($NotificationFunctions->"telegram") do={
+  :local Notification $1;
+
+  :global Identity;
+  :global TelegramChatId;
+  :global TelegramChatIdOverride;
+  :global TelegramFixedWidthFont;
+  :global TelegramQueue;
+  :global TelegramTokenId;
+  :global TelegramTokenIdOverride;
+
+  :global CertificateAvailable;
+  :global CharacterReplace;
+  :global EitherOr;
+  :global IfThenElse;
+  :global LogPrintExit2;
+  :global SymbolForNotification;
+  :global UrlEncode;
+
+  :local EscapeMD do={
+    :global TelegramFixedWidthFont;
+
+    :global CharacterReplace;
+    :global IfThenElse;
+
+    :if ($TelegramFixedWidthFont != true) do={
+      :return ($1 . [ $IfThenElse ($2 = "body") ("\n") "" ]);
+    }
+
+    :local Return $1;
+    :local Chars {
+      "body"={ "\\"; "`" };
+      "plain"={ "_"; "*"; "["; "]"; "("; ")"; "~"; "`"; ">";
+                "#"; "+"; "-"; "="; "|"; "{"; "}"; "."; "!" };
+    }
+    :foreach Char in=($Chars->$2) do={
+      :set Return [ $CharacterReplace $Return $Char ("\\" . $Char) ];
+    }
+
+    :if ($2 = "body") do={
+      :return ("```\n" . $Return . "\n```");
+    }
+
+    :return $Return;
+  }
+
+  :local ChatId [ $EitherOr ($TelegramChatIdOverride->($Notification->"origin")) $TelegramChatId ];
+  :local TokenId [ $EitherOr ($TelegramTokenIdOverride->($Notification->"origin")) $TelegramTokenId ];
+
+  :if ([ :len $TokenId ] = 0 || [ :len $ChatId ] = 0) do={
+    :return false;
+  }
+
+  :local Truncated false;
+  :local Text ("*__" . [ $EscapeMD ("[" . $Identity . "] " . ($Notification->"subject")) "plain" ] . "__*\n\n");
+  :local LenSubject [ :len $Text ];
+  :local LenMessage [ :len ($Notification->"message") ];
+  :local LenLink [ :len ($Notification->"link") ];
+  :local LenSum ($LenSubject + $LenMessage + $LenLink);
+  :if ($LenSum > 3968) do={
+    :set Text ($Text . [ $EscapeMD ([ :pick ($Notification->"message") 0 (3840 - $LenSubject - $LenLink) ] . "...") "body" ]);
+    :set Truncated true;
+  } else={
+    :set Text ($Text . [ $EscapeMD ($Notification->"message") "body" ]);
+  }
+  :if ($LenLink > 0) do={
+    :set Text ($Text . "\n" . [ $SymbolForNotification "link" ] . [ $EscapeMD ($Notification->"link") "plain" ]);
+  }
+  :if ($Truncated = true) do={
+    :set Text ($Text . "\n" . [ $SymbolForNotification "scissors" ] . \
+      [ $EscapeMD ("The Telegram message was too long and has been truncated, cut off " . \
+      (($LenSum - [ :len $Text ]) * 100 / $LenSum) . "%!") "plain" ]);
+  }
+  :set Text [ $UrlEncode $Text ];
+  :local ParseMode [ $IfThenElse ($TelegramFixedWidthFont = true) "MarkdownV2" "" ];
+
+  :do {
+    :if ([ $CertificateAvailable "Go Daddy Secure Certificate Authority - G2" ] = false) do={
+      $LogPrintExit2 warning $0 ("Downloading required certificate failed.") true;
+    }
+    / tool fetch check-certificate=yes-without-crl output=none http-method=post \
+      ("https://api.telegram.org/bot" . $TokenId . "/sendMessage") \
+      http-data=("chat_id=" . $ChatId . "&disable_notification=" . ($Notification->"silent") . \
+      "&disable_web_page_preview=true&parse_mode=" . $ParseMode . "&text=" . $Text) as-value;
+  } on-error={
+    $LogPrintExit2 info $0 ("Failed sending telegram notification! Queuing...") false;
+
+    :if ([ :typeof $TelegramQueue ] = "nothing") do={
+      :set TelegramQueue [ :toarray "" ];
+    }
+    :set Text ($Text . [ $UrlEncode ("\n" . [ $SymbolForNotification "alarm-clock" ] . \
+      [ $EscapeMD ("This message was queued since " . [ / system clock get date ] . \
+      " " . [ / system clock get time ] . " and may be obsolete.") "plain" ]) ]);
+    :set ($TelegramQueue->[ :len $TelegramQueue ]) { chatid=$ChatId; tokenid=$TokenId;
+      parsemode=$ParseMode; text=$Text; silent=($Notification->"silent") };
+    :if ([ :len [ / system scheduler find where name="FlushTelegramQueue" ] ] = 0) do={
+      / system scheduler add name=FlushTelegramQueue interval=1m start-time=startup \
+        on-event=(":global FlushTelegramQueue; \$FlushTelegramQueue;");
+    }
+  }
+}
+
+# send notification via telegram - expects at lease two string arguments
+:set SendTelegram do={
+  :global SendTelegram2;
+
+  $SendTelegram2 ({ subject=$1; message=$2; link=$3; silent=$4 });
+}
+
+# send notification via telegram - expects one array argument
+:set SendTelegram2 do={
+  :local Notification $1;
+
+  :global NotificationFunctions;
+
+  ($NotificationFunctions->"telegram") ("\$NotificationFunctions->\"telegram\"") $Notification;
+}
diff --git a/mod/scriptrunonce b/mod/scriptrunonce
new file mode 100644
index 0000000..0b519c3
--- /dev/null
+++ b/mod/scriptrunonce
@@ -0,0 +1,46 @@
+#!rsc by RouterOS
+# RouterOS script: mod/scriptrunonece
+# Copyright (c) 2020-2021 Christian Hesse <mail@eworm.de>
+# https://git.eworm.de/cgit/routeros-scripts/about/COPYING.md
+
+:global ScriptRunOnce;
+
+# fetch and run script(s) once
+:set ScriptRunOnce do={
+  :local Scripts [ :toarray $1 ];
+
+  :global ScriptRunOnceBaseUrl;
+  :global ScriptRunOnceUrlSuffix;
+
+  :global LogPrintExit2;
+  :global ValidateSyntax;
+
+  :foreach Script in=$Scripts do={
+    :if (!($Script ~ "^(ftp|https\?|sftp)://")) do={
+      :if ([ :len $ScriptRunOnceBaseUrl ] = 0) do={
+        $LogPrintExit2 warning $0 ("Script '" . $Script . "' is not an url and base url is not available.") true;
+      }
+      :set Script ($ScriptRunOnceBaseUrl . $Script . $ScriptRunOnceUrlSuffix);
+    }
+
+    :local Source;
+    :do {    
+      :set Source ([ / tool fetch check-certificate=yes-without-crl $Script output=user as-value ]->"data");
+    } on-error={
+      $LogPrintExit2 warning $0 ("Failed fetching script '" . $Script . "'!") false;
+    }
+
+    :if ([ :len $Source ] > 0) do={
+      :if ([ $ValidateSyntax $Source ] = true) do={
+        :do {
+          $LogPrintExit2 info $0 ("Running script '" . $Script . "' now.") false;
+          [ :parse $Source ];
+        } on-error={
+          $LogPrintExit2 warning $0 ("The script '" . $Script . "' failed to run!") false;
+        }
+      } else={
+        $LogPrintExit2 warning $0 ("The script '" . $Script . "' failed syntax validation!") false;
+      }
+    }
+  }
+}